2015年7月19日 星期日

偷懶用溫度紀錄器

最近弄了機車,
為了確定大太陽底下車廂溫度最高會到多少而弄的小玩意....

設計理念來說,
溫度精準度不用太過計較,MCU有內建最好,
能保存一定數量的溫度紀錄(好畫線XD)
然後使用的東西要儘量簡單&少....

看了看自己手上的MCU:
名稱 溫度計 EEPROM 操作溫度°C
LPC1114 no 用flash代替 -40~85
LPC812 no 用flash代替 -40~105
STM32F103C8T6 yes 用flash代替 -40~105
Atmega328P(pro mini) yes yes -40~85

嚴格說起來STM32F103C8T6是最符合需求的,
只是...手上只有一片&基礎功能都還沒玩過= =
所以就先pass....拿Arduino來繼續偷懶了XD

假設溫度不會到85度....那麼這個裝置就不會有問題....
可是超過85度的話....我想應該會GG吧= =
(至少確定他超過datasheet的工作範圍了...
希望不會超過85度吧....

操作方式:
接上電源自動開始紀錄,最多紀錄169筆,
每5分鐘紀錄一次(第92行可以改)
要讀取的話,
先接好UART轉USB,
然後按一下reset,
會自動跳到顯示模式,
輸入"C"會讓記錄從0開始記;
輸入"F"會把EEPROM設成0xFF;
輸入"D"會把EEPROM裡面所有的資料列出來.

輸出格式為: 時間\t溫度\t電壓
時間為開機後第幾次紀錄,
溫度是攝氏溫度*10(256等於25.6度)
電壓為mV



code:
(使用這個函式庫:http://www.rocketscream.com/blog/2011/07/04/lightweight-low-power-arduino-library/)


pop-uptext
  1. #include <EEPROM.h>
  2. #include "LowPower.h"
  4. int led = 13;
  6. struct Temp{
  7.     unsigned int t;
  8.     int temp;
  9.     unsigned int Vcc;
  10. };
  12. struct Temptab{
  13.     unsigned int num;
  14.     Temp max;
  15. };
  17. char print = 0;
  18. char cmd = 0x00;
  20. Temptab status;
  22. int total = 0;
  23. int offset = sizeof(Temptab);
  24. unsigned int cont = 0;
  26. Temp work;
  27. Temp max = {
  28.     0,
  29.     -64,
  30.     0
  31. };
  33. void setup()
  34. {
  35.     pinMode(led, OUTPUT);
  38.     EEPROM.get( 0, status );
  40.     total = status.num;
  41.     offset = sizeof(Temptab) + status.num * sizeof(Temp);
  43.     if(MCUSR & _BV(EXTRF)){
  44.         Serial.begin(115200);
  45.         print = 1;
  47.         Serial.println( "Read status from EEPROM: " );
  48.         Serial.print( "total\t" );Serial.println( status.num );
  49.         Serial.print( "max_t\t" );Serial.println( status.max.t );
  50.         Serial.print( "max_temp\t" );Serial.println( status.max.temp );
  51.         Serial.print( "max_Vcc\t" );Serial.println( status.max.Vcc );
  53.         if(status.num){
  54.             dump();
  55.         }
  57.     }else{
  58.         LowPower.powerDown(SLEEP_2S, ADC_OFF, BOD_OFF); 
  59.         total++;
  60.         rec();
  61.     }
  62. }
  64. // https://code.google.com/p/tinkerit/wiki/SecretVoltmeter
  65. // The voltage is returned in millivolts. So 5000 is 5V, 3300 is 3.3V.
  66. unsigned int vccVoltage() {
  67.   unsigned int result;
  68.   // Read 1.1V reference against AVcc
  69.   ADMUX = _BV(REFS0) | _BV(MUX3) | _BV(MUX2) | _BV(MUX1);
  70.   delay(2); // Wait for Vref to settle
  71.   ADCSRA |= _BV(ADSC); // Convert
  72.   while (bit_is_set(ADCSRA,ADSC));
  73.   result = ADCL;
  74.   result |= ADCH << 8;
  75.   result = 1126400L / result; // Back-calculate AVcc in mV
  76.   return result;
  77. }
  79. // https://code.google.com/p/tinkerit/wiki/SecretThermometer
  80. // Temperature is returned in 10x°C. So 250 is 25°C.
  81. int readTemp() {
  82.     long result;
  83.     // Read temperature sensor against 1.1V reference
  84.     ADMUX = _BV(REFS1) | _BV(REFS0) | _BV(MUX3);
  85.     delay(50); // Wait for Vref to settle
  86.     ADCSRA |= _BV(ADSC); // Convert
  87.     while (bit_is_set(ADCSRA,ADSC));
  88.     result = ADCL;
  89.     result |= ADCH << 8;
  90.     //result = (result*1000 - 324310L) / 122;
  91.     result = ((result*2000 - 648620L) / 144 + 1) >> 1;
  92.     return result;
  93. }
  95. void sleepMinutes()
  96. {
  97.     for (unsigned int i = 0; i < 150; i++) { 
  98.         LowPower.powerDown(SLEEP_2S, ADC_OFF, BOD_OFF); 
  99.     }
  100.     cont++;
  101. }
  103. void blinkLed(){
  104.     digitalWrite(led, HIGH);
  105.     delay(100);  
  106.     digitalWrite(led, LOW);
  107. }
  109. void rec(){
  110.     work.t = cont;
  111.     work.temp = readTemp();
  112.     work.Vcc = vccVoltage();
  114.     if(work.temp > status.max.temp){
  115.         status.max.t = work.t;
  116.         status.max.temp = work.temp;
  117.         status.max.Vcc = work.Vcc;
  118.     }
  119.     status.num = total;
  121.     EEPROM.put( offset, work );
  122.     EEPROM.put( 0, status );
  124.     total++;
  125.     offset += sizeof(Temp);
  126.     if(offset >= EEPROM.length()){
  127.         total = 0;
  128.         offset = sizeof(Temptab);
  129.     }
  130. }
  132. void dump(){
  133.     unsigned int i = 0;
  135.     EEPROM.get( 0, status );
  136.     Serial.print( "max_time\t" );Serial.println( status.max.t );
  137.     Serial.print( "max_temp\t" );Serial.println( status.max.temp );
  138.     Serial.print( "max_Vcc\t" );Serial.println( status.max.Vcc );
  140.     for(offset=sizeof(Temptab); offset+sizeof(Temp)<=EEPROM.length(); offset+=sizeof(Temp)){
  141.         EEPROM.get( offset, work);
  143.         Serial.print( i++ );Serial.print( "\t" );
  144.         Serial.print( work.t );Serial.print( "\t" );
  145.         Serial.print( work.temp );Serial.print( "\t" );
  146.         Serial.print( work.Vcc );Serial.println();
  147.     }
  148. }
  150. void loop()
  151. {
  152.     if(print == 0){
  153.         blinkLed();
  154.         sleepMinutes();
  155.         rec();
  156.     }else{
  157.         if(Serial.available()){
  158.             cmd = Serial.read();
  159.             if(cmd == 'C'){
  160.                 Serial.print( "clear EEPROM..." );
  161.                 status.num = 0;
  162.                 status.max.t = 65535;
  163.                 status.max.temp = -63;
  164.                 status.max.Vcc = 65535;
  165.                 EEPROM.put( 0, status );
  166.                 Serial.println( "done" );
  167.             }
  168.             if(cmd == 'F'){
  169.                 Serial.print( "set EEPROM to 0xFF..." );
  170.                 for(offset=sizeof(Temptab); offset<EEPROM.length(); offset++){
  171.                     EEPROM.write(offset, 0xFF);
  172.                 }
  173.                 Serial.println( "done" );
  174.             }
  175.             if(cmd == 'D'){
  176.                 Serial.println( "Read status from EEPROM: " );
  177.                 Serial.print( "total\t" );Serial.println( status.num );
  178.                 Serial.println( "dump EEPROM..." );
  179.                 dump();
  180.             }
  181.             if(cmd == 'N'){
  182.                 Serial.print( "now_temp\t" );Serial.println( readTemp() );
  183.                 Serial.print( "now_Vcc\t" );Serial.println( vccVoltage() );
  184.             }
  185.         }
  186.     }
  187. }
張貼者： 於
標籤： , , , , , ,

沒有留言:

張貼留言

訂閱： 張貼留言 (Atom)